Natz's Digital 漂流記

以前のエントリーで Windows 7 の C:\Program Fiels フォルダーを別ドライブに移動させる方法を紹介したが、本エントリーでは以前の加筆修正をまとめて 「x64 対応半自動化版」 とし、改めて 32ビット及び 64ビット環境双方でより汎用的に使える方法を紹介する。

想定する環境は Windows 7 Ultimate の 32ビット版及び 64ビット版。ProgramFiles フォルダーの移動前のパスを C:\Program Files、移動先のパスを D:\Program Files とし、文中では実パスに加え、それぞれ 「旧 ProgramFiles フォルダー」、「移動先 ProgramFiles フォルダー」 とも表記する。表示フォントによってはパス区切り記号の "¥" がバックスラッシュ (半角＼) になるので、"/" と間違えないように注意。

作業の流れは以前と変わらず、次の通り。

1. ローカル Administrator の有効化とパスワード設定。
2. ProgramFiles フォルダーをコピー。
3. レジストリの書き換え。
4. 旧 ProgramFiles フォルダーの削除とシンボリック・リンク作成。
5. 移動先のアプリケーションの動作確認。

1. ローカル Administrator の有効化とパスワード設定

まず、ローカル Administrator を有効化する。任意のユーザーでログオン後、スタート メニューの 「全てのプログラム」 → 「アクセサリ」 → 「コマンド プロンプト」 を右クリック → 「管理者として実行」 でコマンド プロンプトを管理者権限で起動し、次のコマンドを入力する。

・Administrator を有効化
> net user Administrator /active:yes

・パスワードを設定
> net user Administrator <PASSWORD>

・ログオフ
> logoff

管理者権限がない場合は、「システム エラー 5」 「アクセスが拒否されました」 等のエラーが発生する。コマンドが正常に終了したら、ログオフして Administrator でログオンし直す。

2. ProgramFiles フォルダーをコピー

次に旧 ProgramFiles フォルダーをコピーする。基本は xcopy コマンドに適切なオプションを与えて手動コピーだが、同じ作業を繰り返す可能性があるなら、バッチファイルでスクリプト化しておいた方が、ミスをするリスクを軽減できる。

以下のスクリプトは、旧 ProgramFiles フォルダーを所有権、アクセス許可設定、監査設定等を再現しつつ、移動先にコピーする。誤って実行してしまうことを防ぐため、Administrator 以外は実行できない (＝最後に飛ばされる) ようにしている。ファイル名は拡張子が ".bat" なら何でも構わないが、"hoge.bat" にするよりは、例えば "MoveProgramFiles_2_Copy.bat" 等、処理内容を想像できる名前の方がいいと思う。

※ 03/05 追記
日本語環境に存在する "Program Files\Windows NT\アクセサリ" は同じ場所にある "Accessories" へのジャンクションだが、xcopy に /b オプションを付加しても参照先の実体がコピーされてしまう。この対策として、コピー先で "アクセサリ" を一度削除し、改めて同名のジャンクションを作成している。

@echo off
echo ### MOVING PROGRAMFILES: PHASE 2 ###
echo.

if not "%USERNAME%" equ "Administrator" (
    echo Only the Administrator can run this script.
    goto ERROR
)

rem User settings: START ==========
set FromDir=C:\Program Files
set FromDirX86=C:\Program Files (x86)
set ToDir=D:\Program Files
set ToDirX86=D:\Program Files (x86)
rem User settings: END ==========

:X86
if /i "%ProgramFiles%" equ "%FromDir%" (
    if exist "%FromDir%" (
        if not exist "%ToDir%" (
            xcopy /e /h /k /o /x /b /y "%FromDir%" "%ToDir%\"
            if exist "%ToDir%\Windows NT\アクセサリ" (
                takeown /f "%ToDir%\Windows NT\アクセサリ" /r /a /d y
                cacls "%ToDir%\Windows NT\アクセサリ" /t /e /c /g %USERNAME%:f
                rmdir /s /q "%ToDir%\Windows NT\アクセサリ"
                if not exist "%ToDir%\Windows NT\アクセサリ" mklink /j "%ToDir%\Windows NT\アクセサリ" "%ToDir%\Windows NT\Accessories"
            )
        )
    )
)

:X64
if /i "%ProgramFiles(x86)%" equ "%FromDirX86%" (
    if exist "%FromDirX86%" (
        if not exist "%ToDirX86%" (
            xcopy /e /h /k /o /x /b /y "%FromDirX86%" "%ToDirX86%\"
        )
    )
)

:END
echo.
echo Copying ProgramFiles directories was completed.
echo Replace paths in your registry as follows:
if /i "%ProgramFiles%" equ "%FromDir%" (
    echo   "%FromDir%" to "%ToDir%"
)
if /i "%ProgramFiles(x86)%" equ "%FromDirX86%" (
    echo   "%FromDirX86%" to "%ToDirX86%"
)

:ERROR
pause

コピーが完了したら、旧 ProgramFiles フォルダーと移動先 ProgramFiles フォルダーのプロパティ・ウィンドウを並べて、ファイルやフォルダーの数、合計サイズが正しいことを目視確認する。(03/05 追記： xcopy に /b オプションがなかった過去の記事を参考に実施した方は、"Phase 4" のスクリプトを参考に移動先 ProgarmFiles フォルダー内の "WindowsNT\アクセサリ" の所有権とフルコントロールを設定後に削除し、mklink /j で Accessories へのジャンクションを作成すると、同等の結果となる)

尚 「ディスク上のサイズ」 は、それぞれのフォルダーが存在するパーティションのクラスター・サイズ (＝アロケーション・ユニット・サイズ) によっては、一致しないことがある。前述の内容が正しければ、数値が違っていても気にする必要はない。

3. レジストリの書き換え

ProgramFiles フォルダーのコピーが完了したら、レジストリ中に存在する文字列 "C:\Program Files" を "D:\Program Files" に置換する。ただ該当箇所は大量に存在するので、Windows 標準の 「レジストリ エディター」 でチマチマ置換する自信がなければ (僕は無理)、Registry Toolkit や RegGrep (32ビット環境のみ) 等の便利なツールを利用した方がいい。

Registry Toolkit を使う場合は、ツリー構造の "My Registry" を選択した状態でメニューの 「Registry」 → 「Search of Replace in Registry」 ダイアログを表示させ、"Settings" の "Match Case"、"Search/Replace In" の "Data" と "Value" のチェックを ON にして、「Replace」 ボタンをクリックする (各項目名が何を指すのか不明な場合は、こちらのサイトが参考になる)。"Start In:" が "My Registry" 以外になっている場合はレジストリの全域をスキャンできないので、忘れずに確認する。ヒットした文字列を全て置換するには、最初に表示されるダイアログで 「Replace Rest」 ボタンをクリック。

尚、Registry Toolkit はシェアウェア (32ビット版/64ビット版各 $25.00、両方で $35.00。いずれも本エントリー執筆時点での価格) だが、今回限りの利用であれば、未登録状態でも目的は達せられる。もちろんそのまま使い続けたいと思えばライセンス購入を検討すればいいし、他に使い慣れたレジストリ編集ツールがあれば、そちらを使っても一向に構わない。

Registry Toolkit での置換

環境によっては 8.3形式の短いファイル名が使われている可能性もあるので、C:\PROGRA~1 を検索してみて、存在すれば D:\PROGRA~1 に置換する。

さらに、アプリケーション単位の INI ファイル等で旧 ProgramFiles フォルダーがフルパスで指定されている場合も不具合が予想されるので、移動先 ProgramFiles フォルダー内で文字列 "C:\Program Files" を検索する。その際はファイルの内容を検索対象に含めるため、事前に 「フォルダー オプション」 の 「検索」 タブにある 「検索項目」 で、「ファイル名と内容を常に検索する」 を選択しておく。

クリーン・インストール直後の僕の環境 (＝ドライバー類も OS デフォルトのまま) では、8.3形式の ProgramFiles フォルダーのパスや、修正が必要な INI ファイルは見つからなかった。クリーン・インストール直後のように結果が予測できる単純な環境であれば、これらの検索は省略しても問題ないと思う。

旧 ProgramFiles フォルダーを指す全ての文字列置換が完了後、Windows 7 を再起動する。

4. 旧 ProgramFiles フォルダーの削除とシンボリック・リンク作成

旧 ProgramFiles フォルダーを削除する前には、所有権を奪ったり、アクセス許可設定を変更する作業が必要になる。HDD を別のマシンに接続したり、KNOPPIX  等の CD-ROM/DVD-ROM から起動して NTFS パーティションの操作が可能な Linux から削除する方法もあるが、Windows XP にはなかった便利なコマンドが使える Windows 7 では、バッチファイルでスクリプト化しておいて直接実行するのが確実で手っ取り早い。

以下のスクリプトは、takeown で 旧 ProgramFiles フォルダーと 64ビット環境では ProgramFiles(x86) フォルダーの所有権を Administrator に設定し、cacls で Administrator にフルコントロール権限を与えてから rmdir で削除後、mklink で C:\ 直下に移動先 ProgramFiles フォルダーと、64ビット環境では ProgramFiles(x86) フォルダーへのシンボリック・リンクを作成する。旧 ProgramFiles フォルダー削除時に邪魔になるサービス IP Helper は処理前に停止させ、処理後に改めて起動させる。また前述のスクリプト同様、Administrator 以外は実行できない (＝最後に飛ばされる) ようにしている。

ここでもファイル名は何でもいいが、"MoveProgramFiles_4_Remove.bat" 等、処理内容を想像できる名前が望ましい。

@echo off
echo ### MOVING PROGRAMFILES: PHASE 4 ###
echo.

if not "%USERNAME%" equ "Administrator" (
    echo Only the Administrator can run this script.
    goto ERROR
)

rem User settings: START ==========
set FromDir=C:\Program Files
set FromDirX86=C:\Program Files (x86)
set ToDir=D:\Program Files
set ToDirX86=D:\Program Files (x86)
rem User settings: END ==========

net stop "IP Helper"

:X86
if /i "%ProgramFiles%" equ "%ToDir%" (
    if exist "%ToDir%" (
        if exist "%FromDir%" (
            takeown /f "%FromDir%" /r /a /d y
            cacls "%FromDir%" /t /e /c /g %USERNAME%:f
            rmdir /s /q "%FromDir%"
            if not exist "%FromDir%" mklink /d "%FromDir%" "%ToDir%"
        )
    )
)

:X64
if /i "%ProgramFiles(x86)%" equ "%ToDirX86%" (
    if exist "%ToDirX86%" (
        if exist "%FromDirX86%" (
            takeown /f "%FromDirX86%" /r /a /d y
            cacls "%FromDirX86%" /t /e /c /g %USERNAME%:f
            rmdir /s /q "%FromDirX86%"
            if not exist "%FromDirX86%" mklink /d "%FromDirX86%" "%ToDirX86%"
        )
    )
)

net start "IP Helper"
echo.
dir /a C:\
if exist "%ToDir%" (
    echo.
    set ProgramFiles
    set CommonProgramFiles
)

:END
echo.
echo Moving ProgramFiles directories was completed.

:ERROR
pause

シンボリック・リンクは、レジストリの編集不可能な領域に書かれているパス対策。旧 ProgramFiles フォルダーのパスで移動先 ProgramFiles フォルダーにアクセスできるようにするための仕組みで、シンボリック・リンクを作成しない状態では、デスクトップの右クリック・メニューの 「ガジェット」 が機能しなかった。とりあえず他には目立った不具合は見つからなかったが、作成しておいた方がよさそうだ。

5. 移動先のアプリケーションの動作確認

移動させたアプリケーションが正常に動作することを確認し、作業完了。

12 Responses to this entry.